# 004 – Display a sprite

Prerequisite: 001 – Display a background

This tutorial describes:

* How to create a sprite and his logical code
* How to associate images with an object
* How to set the object position on screen and off screen
* Types of image rendering
* The display priority between sprites

Table des matières

[004 – Display a sprite 1](#_Toc87344933)

[Introduction 2](#_Toc87344934)

[Display an overlay sprite 2](#_Toc87344935)

[File structure 2](#_Toc87344936)

[Game Mode definition 4](#_Toc87344937)

[Sprite display main loop 4](#_Toc87344938)

[Engine data structures 5](#_Toc87344939)

[Implement an object 7](#_Toc87344940)

[Display a sprite without affecting the background 13](#_Toc87344941)

[Add a new object 13](#_Toc87344942)

[Sprite coordinates systems 16](#_Toc87344943)

[Screen coordinates 16](#_Toc87344944)

[Playfield coordinates 17](#_Toc87344945)

[Sprite rendering options 18](#_Toc87344946)

[Mirroring 18](#_Toc87344947)

[Wrapping 20](#_Toc87344948)

[Change a sprite image from overlay to normal 20](#_Toc87344949)

[Display an overlay sprite (RLE) 20](#_Toc87344950)

[Display sprites on different layers (priority) 20](#_Toc87344951)

[Use playground coordinates 21](#_Toc87344952)

[Show animated background 21](#_Toc87344953)

## Introduction

The game engine provides multiple ways to display a sprite on TO8.

On many 8/16 bits computers without VDP (Video Display Processor), the fastest way to display an image is to use a “compilated sprite”. It’s an assembly code that will directly writes an image to a memory location, instead of copying data from one memory location to another.

It will be 6x time faster than RLE rendering but does not allow to display an image partially. If the image goes outside the memory location, it will be fully hided to avoid memory corruption.

While you can write compilated sprite by hand, the game engine Builder is able to automatically convert your images into compilated sprites.

The engine only operates graphics in 160x200px 16 colors mode, and provides:

* **display priority** (what sprite should be on top of the others, with 8 layers)
* **screen coordinates** (ability to place a sprite at a screen position)
* **playground coordinates** (ability to place a sprite in a playground, the sprite position on screen will be calculated in conjunction with the camera location).
* **rendering types**:
  + (compilated sprite) write an image
  + (compilated sprite) save background and write an image
  + (RLE) write an image
* **X and/or Y mirroring** (will need duplicate images produced by the Builder)
* **2px or 1px draw precision on x axis** (1px precision will need two images)
* **manual hide** (temporary hide of a sprite)
* **automatic hide** (when a sprite is outside or cross the screen top or bottom)
* **parametric hide** (choose if a sprite should be hidden or not when he crosses the screen left or right limit)
* **automatic erase/draw** (the engine will not redraw a sprite if not required, it’s based on sprite position, collision, image, priority)
* **double buffering** (handle all those functions in a double buffering mode)
* **sprite animations** (see related tutorial)
* **tile map** (see related tutorial)
* **tile map scroll** (see related tutorial)

## Display an overlay sprite

In this first part we are going to display a background and an overlay sprite.

### File structure

For this tutorial, we need to create a game mode and an object.

The game-mode will hold the main loop of the program.

The object will hold the sprite logic.

Create a new folder structure like this one :


Une image contenant texte

Description générée automatiquement

**The configuration of the “config-windows.properties” file is covered by tutorial 000.**

You can place your directory inside the game-project or outside.

As an example, for this directory structure :



You should configure you properties file like this one :



You will notice that relative path should point to the game engine directory.

If the project is inside the game-project directory the relative path will be prefixed by :

../..

If you decided to go outside with a “tutorial” parent directory, it will be :

../../thomson-to8-game-engine

Using an external directory may be useful if you want to use separate repositories (one for the engine, and one or several for your games).

In this tutorial, the game-mode will be named infiniteloop, so you should have this configuration in your .properties file:

gameModeBoot=infiniteloop

gameMode.infiniteloop=./game-mode/infinite-loop/infinite-loop.properties


### Game Mode definition

#### Add a background

Use the tutorial 001 to create a game mode with this background image :



Now you should have this structure :



#### Add an object

To tell what object will be used by this game mode, add this to your infinite-loop.properties :

# Objects

object.foreground=./object/foreground/foreground.properties

When the game-mode will be loaded in RAM, it will also load this object.

**Note :**

There is a way to define common objects for different game modes, it will be covered in a dedicated tutorial.

If you don’t use common objects, when two game modes are using the same object, the object binary is duplicated in the FD/ROM, because :

* the object code is assembled for a specific RAM location
* the data is loaded into RAM by pages, not by objects

The common objects also remains in RAM between a game mode change.

Here is the full properties for this game-mode:



### Sprite display main loop

To display sprites, the main loop of the game mode should have this structure :

MainLoop

        jsr   WaitVBL

        jsr   UpdatePalette

        jsr   RunObjects

        jsr   CheckSpritesRefresh

        jsr   EraseSprites

        jsr   UnsetDisplayPriority

        jsr   DrawSprites

        bra   MainLoop

**WaitVBL**: swap video pages for double buffering

**UpdatePalette** : change palette colors when screen spot is not in the visible area

**RunObjects** : call objects routine

**CheckSpritesRefresh** : check all sprites and flag the ones that needs to be refreshed on screen

**EraseSprites** : clear the sprites on screen when a sprite is deleted or need to be refreshed

**UnsetDisplayPriority** : update the display priority data in case of priority change or sprite removal

**DrawSprites** : write sprites on screen

Here is the full main.asm for this game-mode:



In this file you will see new includes :

        INCLUDE "./game-mode/infinite-loop/main.equ"

        INCLUDE "./Engine/Constants.asm"

        INCLUDE "./game-mode/infinite-loop/ram-object.asm"

### Engine data structures

**main.equ**

This is the file that hold equates definitions.

It is mandatory to size the engine data structures for your game mode, here as we only have one sprite, we will set the nb\_graphical\_objects to 1.

nb\_graphical\_objects               equ 1 ; only count objects that will be rendered on screen (max 64 total)



**ram\_object.asm**

This is the file that defines RAM data space for object variables.

Object\_RAM

                              fcb   ObjID\_foreground

                              fill  0,object\_size-1

Object\_RAM\_End

There is two way of instantiate an object :

* hardcoded
* at runtime

To instantiate an object, simply set the first byte of the object data to the object id.


The object id “equate” is simply a string concatenation of : “ObjID\_” and the object name (as defined in the game mode properties, here: object.sonic)

In this example we are making an hardcoded instantiation.

Dynamic instantiation will be covered in another tutorial, but keep in mind that the engine provides routines to **find** free object data structure, and also routines to **clear** an object data structure.



You should now have this file structure in the infinite-loop directory:



**Engine/Constants.asm**

To help you understand what are the data associated to an object, I just want you to review some content of the engine Constants.asm file.

This is the file that hold equates definitions for all the engine data structures.

Here is the list of equates (available to the developer) for the object data structure :

\* ===========================================================================

\* Object Constants

\* ===========================================================================

object\_size                   equ 114 ; the size of an object - DEPENDENCY ClearObj routine

next\_object                   equ object\_size

id                            equ 0           ; reference to object model id (ObjID\_) (0: free slot)

subtype                       equ 1           ; reference to object subtype (Sub\_)

render\_flags                  equ 2

\* --- render\_flags bitfield variables ---

render\_xmirror\_mask           equ $01 ; (bit 0) DEPENDENCY should be bit 0 - tell display engine to mirror sprite on horizontal axis

render\_ymirror\_mask           equ $02 ; (bit 1) DEPENDENCY should be bit 1 - tell display engine to mirror sprite on vertical axis

render\_overlay\_mask           equ $04 ; (bit 2) DEPENDENCY should be bit 2 - compilated sprite with no background save

render\_motionless\_mask        equ $08 ; (bit 3) tell display engine to compute sub image and position check only once until the flag is removed

render\_playfieldcoord\_mask    equ $10 ; (bit 4) tell display engine to use playfield (1) or screen (0) coordinates

render\_hide\_mask              equ $20 ; (bit 5) tell display engine to hide sprite (keep priority and mapping\_frame)

render\_todelete\_mask          equ $40 ; (bit 6) tell display engine to delete sprite and clear OST for this object

render\_xloop\_mask             equ $80 ; (bit 7) (screen coordinate) tell display engine to hide sprite when x is out of screen (0) or to display (1)

priority                      equ 3           ; display priority (0: nothing to display, 1:front, ..., 8:back)

anim                          equ 4  ; and 5  ; reference to current animation (Ani\_)

prev\_anim                     equ 6  ; and 7  ; reference to previous animation (Ani\_)

anim\_frame                    equ 8           ; index of current frame in animation

anim\_frame\_duration           equ 9           ; number of frames for each image in animation, range: 00-7F (0-127), 0 means display only during one frame

anim\_link                     equ 10          ; allow animation swap without reseting anim\_frame and duration

image\_set                     equ 11 ; and 12 ; reference to current image (Img\_) (0000 if no image)

x\_pos                         equ 13 ; and 14 ; x playfield coordinate

x\_sub                         equ 15          ; x subpixel (1/256 of a pixel), must follow x\_pos in data structure

y\_pos                         equ 16 ; and 17 ; y playfield coordinate

y\_sub                         equ 18          ; y subpixel (1/256 of a pixel), must follow y\_pos in data structure

xy\_pixel                      equ 19          ; x and y screen coordinate

x\_pixel                       equ 19          ; x screen coordinate

y\_pixel                       equ 20          ; y screen coordinate, must follow x\_pixel

x\_vel                         equ 21 ; and 22 ; horizontal velocity

y\_vel                         equ 23 ; and 24 ; vertical velocity

routine                       equ 25          ; index of current object routine

routine\_secondary             equ 26          ; index of current secondary routine

routine\_tertiary              equ 27          ; index of current tertiary routine


routine\_quaternary            equ 28          ; index of current quaternary routine

ext\_variables                 equ 88 ; to 113 ; reserved space for additionnal variables (25 bytes)

There are also “rsv\_” equates (not mentioned here) that are reserved to internal engine routines.

### Implement an object

Create this file and directory structure :



Files for reference :



(for png constraints refers to tutorial 001)

#### Declare sprite images

An object “.properties” file defines :

* assembly code for the object
* images
* animations
* sounds
* …

Here we want to associate a simple image to the object.

code=./object/foreground/foreground.asm

# Sprites

sprite.Img\_foreground=./object/foreground/image/island-overlay.png;ND0

After the image file name, you have to specify an option. It will determine the image types and variations that will be available at runtime (multiple values possible, but only one is mandatory).

Here is a complete list of values (must be comma separated):

* NB0 : no flip, background backup / draw / erase compilated sprite, no x offset
* ND0 : no flip, draw compilated sprite, no x offset
* NB1 : no flip, background backup / draw / erase compilated sprite, 1px x offset
* ND1 : no flip, draw compilated sprite, 1px x offset
* XB0 : x flip, background backup / draw / erase compilated sprite, no x offset
* XD0 : x flip, draw compilated sprite, no x offset
* XB1 : x flip, background backup / draw / erase compilated sprite, 1px x offset
* XD1 : x flip, draw compilated sprite, 1px x offset
* YB0 : y flip, background backup / draw / erase compilated sprite, no x offset
* YD0 : y flip, draw compilated sprite, no x offset
* YB1 : y flip, background backup / draw / erase compilated sprite, 1px x offset
* YD1 : y flip, draw compilated sprite, 1px x offset
* XYB0 : xy flip, background backup / draw / erase compilated sprite, no x offset
* XYD0 : xy flip, draw compilated sprite, no x offset
* XYB1 : xy flip, background backup / draw / erase compilated sprite, 1px x offset
* XYD1 : xy flip, draw compilated sprite, 1px x offset Declare a graphical object (list where it is used)

In this tutorial, we will be using the ND0, that means a simple compilated sprite with no background backup and a positioning precision of 2px in the x coordinates.

**Note:** If you specify only one image (either with no shift or with 1px shift), you have to place this image on odd or even x coordinate. One will display the sprite the other no. It depends on the sprite width and the shift.

Here are the combinations :

- no shift and even witdh will be displayed on even x coordinate.

- no shift and odd witdh will be displayed on odd x coordinate.

- 1px shift and even witdh will be displayed on odd x coordinate.

- 1px shift and odd witdh will be displayed on even x coordinate.

**This may be the number one reason why your sprite won’t show on screen.**

#### Object logical code

The object code defines what assembly code will be executed for the object each time the main game engine loop will be executed.

This code is called by RunObjects with register U loaded with the address of the object structure data.

; ---------------------------------------------------------------------------

; Object - fgrnd

;

; input REG : [u] pointer to Object Status Table (OST)

; ---------

;

; ---------------------------------------------------------------------------

        INCLUDE "./Engine/Macros.asm"

fgrnd

        lda   routine,u

        asla

        ldx   #fgrnd\_Routines

        jmp   [a,x]

fgrnd\_Routines

        fdb   fgrnd\_Init

        fdb   fgrnd\_Main

fgrnd\_Init

        ldb   #1

        stb   priority,u

        ldd   #$807F

        std   xy\_pixel,u

        lda   render\_flags,u

        ora   #render\_overlay\_mask

        sta   render\_flags,u

        ldd   #Img\_foreground

        std   image\_set,u

        inc   routine,u

fgrnd\_Main

        jmp   DisplaySprite

This code is based on a routine lookup table. The routine value can index a maximum of 128 routines.

As the object data is initialized to 0, the first executed routine is always the first in the list, Here fgrnd\_Init.

fgrnd

        lda   routine,u

        asla

        ldx   #fgrnd\_Routines

        jmp   [a,x]

fgrnd\_Routines

        fdb   fgrnd\_Init

        fdb   fgrnd\_Main

The engine handle 4 levels of routines (routine, routine\_secondary, routine\_tertiary, routine\_quaternary), you can add levels if needed thru custom data.

The first execution is used to initialize the object data, it also change the routine to execute the main routine one next step :

        inc   routine,u

There is only one image rendered for each object, you have to create another object to have one more image.

You have to call DisplaySprite each time you want to show the sprite, otherwise it will be hidden.

Here we are using a “jmp DisplaySprite” to avoid making a jsr and next a rts :

        jmp   DisplaySprite

You should have noticed that DisplaySprite is also called in the init routine since there is no rts call between sonic\_init and sonic\_main.

Now that we have the code structure, let see how to assign an active image to the object.

        ldd   #Img\_foreground

        std   image\_set,u

Note : The label refers to the one used in the .properties file

This image should have a position, we will be using screen coordinates :

        ldd   #$807F

        std   xy\_pixel,u

Note : We can also set the x and y position independently with (x\_pixel or y\_pixel)

Ok, I’m sure you want a better way of doing that … because $807F is not quite understandable.

Simply use one of the engine macro and some equates :

        \_ldd  screen\_left+80,screen\_top+99

The sprite will be centered at the 80,99 px screen position, that’s better now …

For an easy positioning the png for this sprite is the size of the screen, so it will align perfectly with the background.

You will have to include the macros at the beginning of your asm file :

        INCLUDE "./Engine/Macros.asm"

Note : All macro names begin with a “\_”

This expression will also use the following engine constants (Engine/Constants.asm), you don’t need to include this file in the object code :

screen\_width                  equ 160    ; in pixel

screen\_top                    equ 28     ; in pixel

screen\_bottom                 equ 28+199 ; in pixel

screen\_left                   equ 48     ; in pixel

screen\_right                  equ 48+159 ; in pixel

The engine provide 8 level of sprite priority (or layer). You must set this parameter, so let’s set it to 1 for this tutorial, values are: 0 (nothing to display), 1 (front), ..., 8(back)

        ldb   #1

        stb   priority,u

The last parameter is only required when you want to display a sprite with no background backup.

        lda   render\_flags,u

        ora   #render\_overlay\_mask

        sta   render\_flags,u

It sets the overlay bit to 1, and tells the engine that we want to use the “D” image (refers to images types ND0, ND1, XD0, …). If the value bit were 0 (default) it would have mean the “B” image (with background backup).

Une image contenant graphiques vectoriels

Description générée automatiquement

**You are ready to build and run your program.**

*Details in 000 tutorial*

The expected result :

Une image contenant texte, équipement électronique, afficher, capture d’écran

Description générée automatiquement

Conclusion:

This first sprite demo show a simple way to “print” a sprite as an overlay. Usually it is used for non-moving objects, or foreground. You can also use it to simulate a continuous pencil draw for example.

If you run a debugger, you will notice that the sprite is only rendered twice, one for each video buffer and so merged with the background. If another sprite in a lower priority layer cross this overlay sprite, the overlay will be automatically refreshed.

## Display a sprite without affecting the background

In this second part we are going to display a moving sprite .

### Add a new object

In the game mode **infinite-loop.properties**, add a new object :

object.sonic=./object/sonic/sonic.properties

In the **ram-object.asm**, add a new object instance for sonic:

Object\_RAM

                              fcb   ObjID\_foreground

                              fill  0,object\_size-1

                              fcb   ObjID\_sonic

                              fill  0,object\_size-1


Object\_RAM\_End

In the **main.equ**, add one more object

nb\_graphical\_objects               equ 2 ; only count objects that will be rendered on screen (max 64 total)

#### Declare sprite images

Create this file and directory structure :



Files for reference :



#### Declare sprite images

Here we want to associate an image to the object.

**sonic.properties**

code=./object/sonic/sonic.asm

# Sprites

sprite.Img\_sonic\_surf=./object/sonic/image/sonic-surf.png;NB0

After the image file name, you will specify NB0. (no flip, background backup / draw / erase compilated sprite, no x offset)

#### Object logical code

**sonic.asm**

; ---------------------------------------------------------------------------

; Object - sonic

;

; input REG : [u] pointer to Object Status Table (OST)

; ---------

;

; ---------------------------------------------------------------------------

        INCLUDE "./Engine/Macros.asm"

sonic

        lda   routine,u

        asla

        ldx   #sonic\_Routines

        jmp   [a,x]

sonic\_Routines

        fdb   sonic\_Init

        fdb   sonic\_Main

sonic\_Init

        ldb   #2

        stb   priority,u

        \_ldd  screen\_left+49,screen\_top+158

        std   xy\_pixel,u

        ldd   #Img\_sonic\_surf

        std   image\_set,u

        inc   routine,u

sonic\_Main

        lda   x\_pixel,u

        adda  #2

        sta   x\_pixel,u

        jmp   DisplaySprite

You will have to include the macros at the beginning of your asm file :

We need to set sonic on a lower layer to be under the overlay sprite (here priority 2).

If you wanted to use layer 1 for sonic, you need to declare sonic before the foreground in Object\_RAM data structure. Sprites on the same layer are stacking from back to front.

        ldb   #2

        stb   priority,u

No need to set the render\_flags, as this type of sprite is the default one.


Une image contenant graphiques vectoriels

Description générée automatiquement

**You are ready to build and run your program.**

*Details in 000 tutorial*

The expected result :



Conclusion:

You now have a smooth 50fps animation with two sprites and an overlay.

The overlay is only refreshed when sonic surfs behind.

## Sprite coordinates systems

There are two coordinates systems for sprite positioning :

* screen (8bits)
* playfield (15bits / 23bits)

### Screen coordinates

This is the default system for an object, simply set x\_pixel and y\_pixel attributes of an object to set his position on screen. Some margins allow you to track the object outside of the screen.


Attributes are:

xy\_pixel                      equ 19          ; x and y screen coordinate

x\_pixel                       equ 19          ; x screen coordinate

y\_pixel                       equ 20          ; y screen coordinate

Note: To have a more explicit code, when setting x and y values with a 16bit operator, use the xy\_pixel equates.



Engine/Constants.asm defines border values :

screen\_width                  equ 160    ; in pixel

screen\_top                    equ 28     ; in pixel

screen\_bottom                 equ 28+199 ; in pixel

screen\_left                   equ 48     ; in pixel

screen\_right                  equ 48+159 ; in pixel

### Playfield coordinates

This system allow to track objects in a bigger space (15bits), each x and y can be set in the 0 to 32767 range. An additional byte makes it possible to manage a precision below one pixel (8bit value, 1/256 pixel precision).

Attributes ares :

x\_pos                         equ 13 ; and 14 ; x playfield coordinate


x\_sub                         equ 15          ; x subpixel (1/256 of a pixel

y\_pos                         equ 16 ; and 17 ; y playfield coordinate

y\_sub                         equ 18          ; y subpixel (1/256 of a pixel

The position on the screen (x\_pixel, y\_pixel) will be calculated according to x\_pos, y\_pos and camera position. The camera does not represents the visible screen area but the screen coordinates system. The camera coordinates should always stays in the 0 to (32767-256) range.

Camera position variables (glb\_camera\_x\_pos, glb\_camera\_y\_pos) are defined in **CheckSpritesRefresh.asm**



**Note:** X\_sub and y\_sub hold remainers when position is calculated from a velocity.

To set the playfield coordinates system for an object, call this:

        lda   render\_flags,u

        ora   #render\_playfieldcoord\_mask

        sta   render\_flags,u

To unset and thus go back to screen coordinates, call this :

        lda   render\_flags,u

        anda  #^render\_playfieldcoord\_mask

        sta   render\_flags,u

## Sprite rendering options

This chapter describes the sprites rendering options.

### Mirroring

The engine provides a convenient way of dealing with mirrored sprites, even if we are using compiled sprites.

To be able to display a x mirrored sprite, first add the appropriate image option in the object properties files. We want a x mirrored, background saving and no offset sprite, we will set the XB0 option (other options are YB0 and XYB0 to mirror on y and xy axis).

**sonic.properties**

# Sprites

sprite.Img\_sonic\_surf=./object/sonic/image/sonic-surf.png;NB0,XB0

Now we are able to flip the sprite “on demand” at the runtime.

To set the x mirrored sprite call this :

        lda   render\_flags,u

        ora   #render\_xmirror\_mask

        sta   render\_flags,u

To unset the x mirrored sprite call this :

        lda   render\_flags,u

        anda  #^render\_xmirror\_mask

        sta   render\_flags,u

**Notes :**

* For y axis use : render\_ymirror\_mask
* For xy axis use (render\_xmirror\_mask|render\_ymirror\_mask) expression

**To test this, in the sonic.asm source file :**

* **place the set x mirror code in the sonic\_Init routine:**

sonic\_Init

        ldb   #2

        stb   priority,u

        \_ldd  screen\_left+49,screen\_top+158

        std   xy\_pixel,u

        ldd   #Img\_sonic\_surf

        std   image\_set,u

        lda   render\_flags,u

        ora   #render\_xmirror\_mask

        sta   render\_flags,u

        inc   routine,u

* **place the unset x mirror code in the sonic\_Main routine when Sonic reaches the right border of the screen :**

sonic\_Main

        lda   x\_pixel,u

        adda  #2

        cmpa  #screen\_right

        bls   @a

        lda   render\_flags,u

        anda  #^render\_xmirror\_mask

        sta   render\_flags,u

        lda   #screen\_left

@a      sta   x\_pixel,u

        jmp   DisplaySprite

Une image contenant graphiques vectoriels

Description générée automatiquement

**You are ready to build and run your program.**

*Details in 000 tutorial*

The expected result :

Une image contenant ciel, bleu, jouet

Description générée automatiquement

**Note :**

The mirroring will work with all types of sprites : overlay, RLE, with or without offset.

### Wrapping

While the engine automatically hide the sprites when pixels are outside the top or bottom border to prevent memory corruption, it is not mandatory for left and right border.

By default, when a pixel get outside the left or right border, the sprite is hidden. There is an option to allow the sprite to wrap the opposite side of the screen.

**…**

**TODO :**

Use the code of the overlay sprite and convert to a sprite

Hide/show the object

Delete the object (show that the object is removed from screen)

Nonmoving option

Explain double buffering and background save

Show wrap and hide for x axis

Show auto hide for top and bottom

## Change a sprite image from overlay to normal

Declare an image as overlay and normal, and x y and 1px

Switch between overlay and normal mode (like a stamp mode)

Switch to 2px or 1px mode

## Display an overlay sprite (RLE)

Declare an image as RLE overlay and show size gain (bytes)

Show cycle count between compilated sprite and RLE with dcmoto debug mode

(Conclude that it is best to use when no speed is required)

## Display sprites on different layers (priority)

Create many sprites on different priority layers

Show dynamic layer change (press of a button)

Explain automatic redraw of moving / priority changing sprites

## Use playground coordinates

Presents the example of the sword in Zelda

Use joypad control

## Show animated background